## Process this file with autoconf to produce configure script

## Copyright (C) 2017 Samediggi/Divvun/UiT

## This program is free software: you can redistribute it and/or modify
## it under the terms of the GNU General Public License as published by
## the Free Software Foundation, either version 3 of the License, or
## (at your option) any later version.

## This program is distributed in the hope that it will be useful,
## but WITHOUT ANY WARRANTY; without even the implied warranty of
## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
## GNU General Public License for more details.

## You should have received a copy of the GNU General Public License
## along with this program.  If not, see <http://www.gnu.org/licenses/>.

# The following things need to be at top of all configure.ac files:

# AC_INIT sets up project metadata:
# first field the name of the "software"
# second field is version identifier
# third is email address for bug reports
# fourth is name of packages made by make dist, excluding .tar.gz
# fifth is the project web address
AC_INIT([GiellaLT-svn-admin], [0.1.0], [feedback@divvun.no], [giellalt-svn-admin],
        [http://divvun.no])
# AC_REVISION is used to get SVN revision into bug reports
AC_REVISION([$Revision$])
# These configuration dirs hide some extra cruft
AC_CONFIG_AUX_DIR([build-aux])
# xxx AC_CONFIG_MACRO_DIR([m4])
# AM_INIT_AUTOMAKE sets up make conventions
AM_INIT_AUTOMAKE(
  1.11.6 tar-pax -Wall -Werror
  foreign -Wno-portability
  dnl Automake versions before 1.13 (when the serial-tests option was
  dnl still the default) still defined the badly obsolete macro
  dnl 'AM_PROG_CC_STDC'. By checking for the non-existence of this macro,
  dnl we can now force serial testing for newer automakes (with prettier
  dnl output) and at the same time work reasonably with older automakes.
  dnl Code based on:
  dnl https://lists.gnu.org/archive/html/automake/2013-01/msg00060.html
  m4_ifndef([AM_PROG_CC_STDC], [serial-tests])
)
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])

AC_MSG_CHECKING([whether we can set GIELLA_CORE])

# --with-giella-core overrides everything:
AS_IF([test "x$with_giella_core" != "xfalse" -a \
          -d "$with_giella_core/scripts" ], [
    GIELLA_CORE=$with_giella_core
    ],[
    # GIELLA_CORE is the env. variable for this dir:
    AS_IF([test "x$GIELLA_CORE" != "x" -a \
              -d "$GIELLA_CORE/scripts"], [], [
        # Look in the parent dir:
        AS_IF([test -d "../giella-core/scripts"], [
            GIELLA_CORE=../giella-core
        ], [
            # GTHOME for backwards compatibility - it is deprecated:
            AS_IF([test "x$GTHOME" != "x" -a \
                      -d "$GTHOME/giella-core/scripts"], [
                GIELLA_CORE=$GTHOME/giella-core
            ], [
                # GTCORE for backwards compatibility - it is deprecated:
                AS_IF([test "x$GTCORE" != "x" -a \
                          -d "$GTCORE/scripts"], [
                    GIELLA_CORE=$GTCORE
                ], [
                    # Try the gt-core.sh script. NB! It is deprecated:
                    AS_IF([test "x$GTCORESH" != xfalse -a \
                           -d "$(${GTCORESH})/scripts"], [
                        GIELLA_CORE=$(${GTCORESH})
                    ], [
                       # If nothing else works, try pkg-config:
                       AS_IF([pkg-config --exists giella-core], [
                           GIELLA_CORE=$(pkg-config --variable=dir giella-core)
                       ], [
                       AC_MSG_ERROR([${_giella_core_not_found_message}])
                       ])
                   ])
                ])
            ])
        ])
    ])
])
AC_MSG_RESULT([$GIELLA_CORE])
AC_ARG_VAR([GIELLA_CORE], [directory for the Giella infra core scripts and other required resources])

AC_PATH_PROG([GUT], [gut], [false])

AC_CONFIG_FILES([Makefile ])

# This must be near the end of all configure.ac files:
AC_OUTPUT